| #!/usr/bin/env gnuplot -c |
| # == DEFINICIONS == |
| outputfile = ARG2 # Nom de la imatge resultant (sense extensió) |
| datafile = ARG1 # Nom del fitxer de dades que es vol usar |
| |
| # == CONFIGURACIÓ DE L'OUTPUT PEL LATEX == |
| set terminal cairolatex size 10cm, 10cm |
| set output outputfile.'.tex' |
| |
| # == CONFIGURACIÓ DEL PLOT == |
| set xlabel "$t \\, (\\si{\\second})$" |
| set ylabel "$\\varepsilon \\, (\\si{\\milli\\volt})$" |
| |
| set autoscale yfixmin |
| set autoscale xfixmax |
| |
| # Opcions per la llegenda: |
| set key above |
| set key spacing 1.5 |
| |
| # == CONFIGURACIÓ DEL FIT == |
| #set fit quiet |
| |
| # Funció per obtenir els dígits significatius d'una expressió |
| f_sd(n, i) = (int(n) == 0 ? f_sd(n*10, i+1) : (int(n) == 1 ? i+1 : i)) |
| significant_digits(n) = f_sd(n - 10*int(n/10), 0) |
| |
| significant_digits_r(n) = (n == 1 ? 0 : significant_digits(1 - n)) |
| |
| p(x) = a*x + b*x*x # Funció a fitar |
| fit p(x) datafile u 1:2 via a, b # Fem el fit de les dades |
| |
| plot [-50:150] datafile u 1:2:(0):3 w xyerr t "Dades", p(x) t "$\\varepsilon(t)$" |
| |
| # == CONFIGURACIÓ DE L'OUTPUT PER SVG == |
| # Això ho uso per generar també una imatge de previsualització que puc carregar |
| # a l'ordinador per veure més o menys com a sortit el plot sense haver |
| # d'inserir-ho al LaTeX per veure-ho. |
| set terminal svg dashed size 600, 600 font "Computer Modern,Tinos,Helvetica,15" |
| set output outputfile.'.svg' |
| |
| replot |