| avm99963 | f7ad158 | 2021-05-26 00:17:58 +0200 | [diff] [blame^] | 1 | #!/usr/bin/env gnuplot -c |
| 2 | # == DEFINICIONS == |
| 3 | outputfile = '../output/6_3_2_1' # Nom de la imatge resultant (sense extensió) |
| 4 | datafile = '../data/6_3_2_1.dat' # Nom del fitxer de dades que es vol usar |
| 5 | |
| 6 | # == CONFIGURACIÓ DE L'OUTPUT PEL LATEX == |
| 7 | set terminal cairolatex size 10cm, 7.5cm font ",10" |
| 8 | set output outputfile.'.tex' |
| 9 | |
| 10 | # == CONFIGURACIÓ DEL PLOT == |
| 11 | set xlabel '$\tan(\alpha) =: x$' |
| 12 | set ylabel '$B_b \, (\si{\milli\tesla)}$' |
| 13 | |
| 14 | # Opcions per la llegenda: |
| 15 | set key above |
| 16 | set key spacing 1.5 |
| 17 | set key font ",8.5" |
| 18 | |
| 19 | # == CONFIGURACIÓ DEL FIT == |
| 20 | set fit quiet |
| 21 | |
| 22 | f(x) = a*x + b # Funció a fitar |
| 23 | fit f(x) datafile u 4:3 via a, b # Fem el fit de les dades |
| 24 | |
| 25 | # Això s'usa per obtenir el valor del coeficient de correlació "r", que estarà |
| 26 | # guardat a la var. "STATS_correlation" |
| 27 | stats datafile u 4:3 name "STATS" nooutput |
| 28 | |
| 29 | # Funció per obtenir els dígits significatius d'una expressió |
| 30 | f_sd(n, i) = (int(n) == 0 ? f_sd(n*10, i+1) : (int(n) == 1 ? i+1 : i)) |
| 31 | significant_digits(n) = f_sd(n - 10*int(n/10), 0) |
| 32 | |
| 33 | significant_digits_r(n) = (n == 1 ? 0 : significant_digits(1 - abs(n))) |
| 34 | |
| 35 | error_a = STATS_slope_err |
| 36 | sd_error_a = significant_digits(error_a) |
| 37 | error_b = STATS_intercept_err |
| 38 | sd_error_b = significant_digits(error_b) |
| 39 | r = STATS_correlation |
| 40 | sd_r = significant_digits_r(r) |
| 41 | |
| 42 | print("=== ".datafile." ===") |
| 43 | print(sprintf('delta(a) = %.'.sd_error_a.'f, sd=%.0f', error_a, sd_error_a)) |
| 44 | print(sprintf('delta(b) = %.'.sd_error_b.'f, sd=%.0f', error_b, sd_error_b)) |
| 45 | |
| 46 | # Aquesta funció escriu, a partir dels valors del paràmetres a, b i r, |
| 47 | # l'equació de la regressió: |
| 48 | title_f(a, b, r) = sprintf('$B_b(x) = %.'.sd_error_a.'f x + (%.'.sd_error_b.'f)$, $r = %.'.sd_r.'f$', a, b, r); |
| 49 | |
| 50 | plot datafile u 4:3:5 t "Dades experimentals" w xerr, f(x) t title_f(a, b, r) |
| 51 | |
| 52 | # == CONFIGURACIÓ DE L'OUTPUT PER SVG == |
| 53 | # Això ho uso per generar també una imatge de previsualització que puc carregar |
| 54 | # a l'ordinador per veure més o menys com a sortit el plot sense haver |
| 55 | # d'inserir-ho al LaTeX per veure-ho. |
| 56 | set terminal svg dashed size 600, 600 font "Computer Modern,Tinos,Helvetica,15" |
| 57 | set output outputfile.'.svg' |
| 58 | replot |