Adrià Vilanova Martínez | 1e4c224 | 2021-06-13 13:34:26 +0200 | [diff] [blame^] | 1 | #!/usr/bin/env gnuplot -c |
| 2 | # == DEFINICIONS == |
| 3 | outputfile = ARG2 # Nom de la imatge resultant (sense extensió) |
| 4 | datafile = ARG1 # Nom del fitxer de dades que es vol usar |
| 5 | datafitfile = ARG4 |
| 6 | |
| 7 | # == CONFIGURACIÓ DE L'OUTPUT PEL LATEX == |
| 8 | set terminal cairolatex size 7.5cm, 7.5cm font ",10" |
| 9 | set output outputfile.'.tex' |
| 10 | |
| 11 | # == CONFIGURACIÓ DEL PLOT == |
| 12 | set xlabel '$\frac{1}{T} \, (\si{\per\kelvin})$' |
| 13 | set ylabel '$\log(\mu \cdot \si{\second\per\milli\pascal})$' |
| 14 | |
| 15 | set yrange [0:] |
| 16 | |
| 17 | # Opcions per la llegenda: |
| 18 | set key above |
| 19 | set key spacing 1.5 |
| 20 | set key font ",8.5" |
| 21 | |
| 22 | # == FIT == |
| 23 | set fit quiet |
| 24 | |
| 25 | # Funció per obtenir els dígits significatius d'una expressió |
| 26 | f_sd(n, i) = (int(n) == 0 ? f_sd(n*10, i+1) : (int(n) == 1 ? i+1 : i)) |
| 27 | significant_digits(n) = f_sd(n - 10*int(n/10), 0) |
| 28 | |
| 29 | significant_digits_r(n) = (n == 1 ? 0 : significant_digits(1 - abs(n))) |
| 30 | |
| 31 | f(x) = a*x + b |
| 32 | fit f(x) datafile u (1/($4 + 273.15)):(log($2)) via a, b |
| 33 | stats datafile u (1/($4 + 273.15)):(log($2)) name "STATS" nooutput |
| 34 | error_a = STATS_slope_err |
| 35 | sd_error_a = significant_digits(error_a) |
| 36 | error_b = STATS_intercept_err |
| 37 | sd_error_b = significant_digits(error_b) |
| 38 | r = STATS_correlation |
| 39 | sd_r = significant_digits_r(r) |
| 40 | title_f(a, b, r) = sprintf('($\log(\mu)) \left(\frac{1}{T}\right) = %.'.sd_error_a.'f \frac{1}{T} + (%.'.sd_error_b.'f$), $r = %.'.sd_r.'f$', a, b, r); |
| 41 | |
| 42 | print(sprintf('delta(a) = %.'.sd_error_a.'f, sd=%.0f', error_a, sd_error_a)) |
| 43 | print(sprintf('delta(b) = %.'.sd_error_b.'f, sd=%.0f', error_b, sd_error_b)) |
| 44 | print(sprintf('r = %.'.sd_r.'f, sd=%.0f', r, sd_r)) |
| 45 | |
| 46 | set xtics 0.0001 |
| 47 | |
| 48 | plot datafile u (1/($4 + 273.15)):(log($2)):(0.2/((($4 + 273.15)**2))):(5/$2) w xyerr ps 0.8 pt 2 lc ARG3 t "Experimental data", \ |
| 49 | f(x) t title_f(a, b, r) |
| 50 | |
| 51 | # == CONFIGURACIÓ DE L'OUTPUT PER SVG == |
| 52 | # Això ho uso per generar també una imatge de previsualització que puc carregar |
| 53 | # a l'ordinador per veure més o menys com a sortit el plot sense haver |
| 54 | # d'inserir-ho al LaTeX per veure-ho. |
| 55 | set terminal svg dashed size 600, 600 font "Computer Modern,Tinos,Helvetica,15" |
| 56 | set output outputfile.'.svg' |
| 57 | replot |