quad10/fenomens/lab/p3/graphs/different_temp.gnu

#!/usr/bin/env -S gnuplot -c
outputfile = 'diferent_t' # Nom de la imatge resultant (sense extensió)
datafilepre = 'SIM-L-32-TEMP-'
datafilepost = '-MCTOT-10000.out'
L=32
TEMPS="1500 1800 2500 3500 4500"

do for [IDX = 0:1] {
  if (IDX == 0) {
    set terminal cairolatex size 8.5cm, 11cm
    set output outputfile.'.tex'
  } else {
    set terminal svg dashed size 600, 1200 font "Computer Modern,Tinos,Helvetica,15"
    set output outputfile.'.svg'
  }

  set multiplot layout 2,1
  set key outside top horizontal

  set xlabel "Iteracions MC"
  set ylabel '$\langle e \rangle$'
  set yrange [-2:0]
  plot for [T in TEMPS] datafilepre . T . datafilepost using 1:($2/(L*L)) with lines title sprintf("T = %.1f", (T+0.0)/1000)

  set xlabel "Iteracions MC"
  set ylabel '$\langle m \rangle$'
  set yrange [-1:1]
  plot for [T in TEMPS] datafilepre . T . datafilepost using 1:($3/(L*L)) with lines title sprintf("T = %.1f", (T+0.0)/1000)

  unset multiplot
}