Continuum mechanics: Add long report for session 2
Change-Id: I597cf2f136f6cf7b7a2b771428d4cc4c8a7337d8
diff --git a/quad8/continuummechanics/lab/p2/graphs/viscosity_vs_t_3p.gnu b/quad8/continuummechanics/lab/p2/graphs/viscosity_vs_t_3p.gnu
new file mode 100755
index 0000000..593bb02
--- /dev/null
+++ b/quad8/continuummechanics/lab/p2/graphs/viscosity_vs_t_3p.gnu
@@ -0,0 +1,36 @@
+#!/usr/bin/env gnuplot -c
+# == DEFINICIONS ==
+outputfile = ARG2 # Nom de la imatge resultant (sense extensió)
+datafile = ARG1 # Nom del fitxer de dades que es vol usar
+datafitfile = ARG4
+
+# == CONFIGURACIÓ DE L'OUTPUT PEL LATEX ==
+set terminal cairolatex size 7.5cm, 7.5cm font ",10"
+set output outputfile.'.tex'
+
+# == CONFIGURACIÓ DEL PLOT ==
+set xlabel '$T \, (\si{\kelvin})$'
+set ylabel '$\mu \, (\si{\milli\pascal\per\second})$'
+
+set yrange [0:]
+
+# Opcions per la llegenda:
+set key above
+set key spacing 1.5
+set key font ",8.5"
+
+# == FIT ==
+f(x) = a*exp(b/(x - c))
+fit f(x) datafile u ($4 + 273.15):2 via a, b, c
+title_f(a, b, c) = sprintf('$\mu(T) = %.2f \exp\left( \frac{%.1f}{T - (%.2f)} \right)$', a, b, c);
+
+plot datafile u ($4 + 273.15):2:(0.2):(5) w xyerr ps 0.8 pt 2 lc ARG3 t "Experimental data", \
+ f(x) t title_f(a, b, c)
+
+# == CONFIGURACIÓ DE L'OUTPUT PER SVG ==
+# Això ho uso per generar també una imatge de previsualització que puc carregar
+# a l'ordinador per veure més o menys com a sortit el plot sense haver
+# d'inserir-ho al LaTeX per veure-ho.
+set terminal svg dashed size 600, 600 font "Computer Modern,Tinos,Helvetica,15"
+set output outputfile.'.svg'
+replot